Überblick

Dieses Worksheet visualisiert den Begriff des Gradienten einer Funktion. Nach einer Begriffserläuterung, in der auch die Berechnung des Gradienten mit Maple beschrieben wird, folgt zunächst die Darstellung einer Funktion von zwei Variablen als dreidimensionales Schaubild, das in einer Animation zu einer Höhenliniendarstellung übergeht. Anschließend erfolgt die Darstellung des Gradienten zusammen mit den Höhenlinien der Funktion. Zum Abschluss vertiefen Beispiele aus der Physik den Begriff des Gradienten.

Inhaltsverzeichnis

Begriffserläuterung und Berechnung des Gradienten

Darstellung einer Funktion von zwei Variablen

Darstellung des Gradienten einer Funktion von zwei Variablen

Darstellung des Gradienten einer Funktion von drei Variablen

Beispiele aus der Physik

-----------------------

zurück zur Startseite

Begriffserläuterung und Berechnung des Gradienten

Wir wollen zunächst den Begriff Gradient näher erläutern. Gegeben sei eine skalare Funktion f(x,y,z), die von den Variablen x, y und z abhängt. Eine skalare Funktion besitzt im Gegensatz zu einer vektoriellen nur Funktionswerte, jedoch keine Richtung.

Um den Gradienten der skalaren Funktion f zu berechnen, muss diese nach jeder Variablen (x,y,z) partiell abgeleitet werden. Die Ergebnisse bilden die Komponenten eines Vektors, dem Gradienten der Funktion f. Durch die Gradientenbildung erhält man also aus einer skalaren eine vektorielle Funktion, die neben ihrem Betrag auch durch die Richtung in jedem Raumpunkt definiert ist. Ein Beispiel für ein Vektorfeld ist eine Wasserströmung: Jedem Punkt der Stömung wird ein Geschwindigkeitsvektor zugeordnet.

Der zugehörige Maple-Befehl zur Berechnung des Gradienten lautet grad . Er besitzt im Normalfall zwei Parameter: der erste ist die zu berechnende Funktion, der zweite einen Liste der abhängigen Variablen (innerhalb einer "eckigen" Klammer und durch Kommas getrennt). Die Anzahl der Variablen gibt die Dimension des Gradienten an.
> Gradient:=grad(f(x,y,z),[x,y,z]);

Der Gradient hat im wesentlichen folgende Eigenschaften:
1. Der Gradient steht senkrecht auf den "Höhenlinien" und zeigt in Richtung des steilsten Anstieges bzw. des steilsten Abfalls.
2. Der Betrag des Gradienten ist ein Maß für die Änderung des Funktionswertes senkrecht zu den "Höhenlinien". ( Höhenlinien sind Linien, auf denen die Funktion gleiche Funktionswerte besitzt.)

zurück zum Anfang

Darstellung einer Funktion von zwei Variablen

Die Prozedur Funktion2d stellt eine Funktion von zwei Variablen graphisch als Animation unter unterschiedlichen Blickwinkeln dar. Zunächst erfolgt die Darstellung als dreidimensionales, farbiges Schaubild, anschließend werden die Höhenlinien eingeblendet und nur noch die Grauschattierung der Funktion dargestellt.
> f:=4/(1+x^2+y^2);
> Funktion2d(f, x=-2..2, y=-2..2);

animierte 3D-Darstellung !

zurück zum Anfang

Darstellung des Gradienten einer Funktion von zwei Variablen

Um den Gradienten der Funktion zu erhalten, muss die Funktion f(x,y) partiell nach x und y abgeleitet werden. Das Ergebnis ist eine vektorielle Funktion. Der resultierende Vektor zeigt für jeden beliebigen Punkt jeweils in die Richtung der größten Funktionszunahme (und steht damit senkrecht auf die Niveauflächen der Funktion).

Da der Gradient ein Vektorfeld ist, besitzt er in jedem Punkt des Raumes einen Betrag und eine Richtung. Dies kann mit Hilfe von Pfeilen dargestellt werden, wobei die Pfeillänge dem Betrag entspricht. Der Befehl gradplot ermöglicht es, beliebige 2-dimensionale Funktionen mit Hilfe von Pfeilen als Vektorfeld darzustellen. Mit der Option arrows kann die Form bzw. Dicke der Pfeile verändert werden.
> p1:=gradplot(f,x=-2..2,y=-2..2, arrows=THICK, grid=[10,10], color=red):
> p2:=contourplot(f, x=-3..3, y=-3..3, grid=[30,30], contours=10, color=black):
> ttl:=`Höhenlinien u. Gradient der Funktion f`:
> display([p1,p2],scaling=constrained, title=ttl);

An diesem Plot erkennt man, dass die Vektorpfeile senkrecht zu den Höhenlinien stehen. Die Größe der Pfeile und damit der Betrag des Gradienten, ist ein Maß für die Änderung des Funktionswertes senkrecht zu den Höhenlinien. Sind die Höhenlinien eng beeinander bzw. ist die Steigung der Funktion an diesem Ort groß, so ist der Betrag des Gradienten ebenfalls groß und die Vektorpfeile werden dicker dargestellt.

zurück zum Anfang

Darstellung des Gradienten einer Funktion von drei Variablen

Im folgenden Plot wird der Gradient einer Funktion mit 3 Variablen als Pfeile dreidimensional im Raum durch den Maple-Befehl gradplot3d dargestellt.
> f2:=-1/(1+x^2+y^2+z^2);
> gradplot3d(f2,x=-2..2,y=-2..2,z=-1..1,axes=boxed, orientation=[20,62], color=red, grid=[5,5,5], arrows=THICK);

3D-Darstellung !

zurück zum Anfang

Beispiele aus der Physik

Eine wichtige Anwendung des Gradienten in der Physik ist die Berechnung des elektrischen Feldes E aus einer gegebenen Potentialfunktion . Die zugehörige Formel lautet:

Auch hier gelten die schon zuvor beschriebenen Eigenschaften des Gradienten:
1. Das elektrische Feld steht senkrecht auf den Potentiallinien und zeigt in Richtung des steilsten Potentialanstiegs.
2. Der Betrag des elektrischen Feldes ist ein Maß für die Änderung des Potentials.

Potential und elektrisches Feld einer Punktladung

Bei einer Punktladung ist die Ladung q auf einen unendlich kleinen Punkt beschränkt. Das Potential einer Punktladung (hier: positive Ladung) wird durch folgende Formel beschrieben:

bzw. wenn man den Abstand r (für den 2-dimensionalen Fall) durch ersetzt und die Normierungskonstante auf 1 setzt:

Im folgenden Plot wird das Potential mit Hilfe des Befehls densityplot , die Höhenlinien mit contourplot und das elektrische Feld mit Hilfe des Befehls gradplot dargestellt. densityplot stellt die Funktionswerte als Graustufen dar; dabei entsprechen helle Grautöne hohen Funktionswerten. Die Option style = <patchnogrid> sorgt dafür, dass keine Rasterlinien angezeigt werden. Der Befehl gradplot ermöglicht es, beliebige 2-dimensionale Funktionen mit Hilfe von Pfeilen als Vektorfeld darzustellen. Mit der Option color kann die Farbe der Vektorpfeile gewählt werden, grid gibt die Anzahl der zu berechnenden Datenpunkte einer zweidimensionalen Datenmenge in x- und y-Richtung an und mit arrows kann die Form der Pfeile verändert werden. Mit scaling =constrained erhält man eine unverzerrte Ausgabe des Plots, wobei für die x-und die y-Achse die gleiche Skalierung verwendet wird. Mit der Defaulteinstellung scaling =unconstrained wird der gesamte zur Verfügung stehende Raum zur Darstellung des Plots genutzt, dies kann aber zu Verzerrungen führen (z.B. werden Kreise als Ellipsen dargestellt)! axes bestimmt das Aussehen der Koordinatenachsen.

Da das Potential einer Punktladung am Ort der Punktladung gegen unendlich geht, wird die Funktion mit Hilfe der Heaviside -Funktion ab einem bestimmten Funktionswert (hier 5) abgeschnitten. Die Heaviside -Funktion liefert 0 für x<0 und 1 für x>0. Man beachte, dass beim gradplot -Befehl als skalare Funktion eingegeben werden muss, da aufgrund der physikalischen Festlegung E= -grad ist.

> restart: with(plots): phi:=1/sqrt(x^2+y^2);
> p1:=densityplot(phi*Heaviside(5-phi), x=-1..1, y=-1..1, grid=[60,60], style=patchnogrid):
> p2:=gradplot(-phi, x=-1..1, y=-1..1, color=red, grid=[9,9], arrows=THICK):
> p3:=contourplot(phi, x=-2..2, y=-2..2, color=white, numpoints=1000, contours=8):
> ttl:=`E-Feld und Potential einer Punktladung`:

> display({p1,p2,p3},scaling=constrained,axes=none,title=ttl);

Wie wir aus dieser Grafik sehen, fällt das Potential der Punkladung radial nach außen hin ab. Die Vektorpfeile, also das elektrische Feld, stehen senkrecht auf den Potentiallinien und nehmen mit größer werdendem Abstand von der Punktladung ab. Der schwarze Punkt in der Mitte entsteht durch das Abschneiden der Potentialfunktion mit Hilfe des Heaviside -Befehls.

zurück zum Anfang

Potential und elektrisches Feld eines Quadrupols

Ein Quadrupol ist ein Gebilde, das sich aus 4 an unterschiedlichen Orten befindlichen Punktladungen (2 positive und 2 negative Ladungen) zusammensetzt (siehe Bild).

Wir werden uns dessen Potentialverteilung und sein elektrisches Feld näher ansehen. Dazu definieren wir uns zunächst das Potential des Quadrupols. Mit Hilfe der Variablen x1 bis x4 wird der Ort der jeweiligen Ladung in x-Richtung angegeben. Die Variablen y1 bis y4 dienen zur Ortsangabe in y-Richtung.

Die in diesem Beispiel verwendeten Maple-Befehle werden nicht näher erläutert, können aber im Beispiel "Potential und elektrisches Feld einer Punktladung" in diesem Worksheet nachgelesen werden.

Man beachte, dass beim gradplot -Befehl als skalare Funktion eingegeben werden muss, da aufgrund der physikalischen Festlegung E= -grad ist.

> restart: with(plots):
> phi:=1/sqrt((x-x1)^2+(y-y1)^2) - 1/sqrt((x-x2)^2+(y-y2)^2) + 1/sqrt((x-x3)^2+(y-y3)^2) - 1/sqrt((x-x4)^2+(y-y4)^2);
> x1:=-0.5: y1:=-0.5:
> x2:=+0.5: y2:=-0.5:
> x3:=+0.5: y3:=+0.5:
> x4:=-0.5: y4:=+0.5:

> p1:=densityplot(phi*Heaviside(phi+5)*Heaviside(5-phi), x=-1..1, y=-1..1, style=patchnogrid, grid=[60,60]):
> p2:=gradplot(-phi,x=-1..1,y=-1..1,grid=[9,9], arrows=THICK, color=red):
> p3:=contourplot(phi,x=-1..1,y=-1..1,color=white, numpoints=500,contours=27):
> ttl:=`E-Feld und Potential eines Quadrupols`:

> display({p1,p3,p2},scaling=constrained,axes=none, title=ttl);

Beim Quadrupol beeinflussen sich die elektrischen Felder bzw. die Potentialverteilung der einzelnen Punktladungen gegenseitig. Dabei wird in der Mitte durch Aufsummieren der einzelnen Felder ein potentialfreier Raum erreicht. Man sieht außerdem, dass das elektrische Feld von der positiven zur negativen Ladung zeigt.

zurück zum Anfang

Potential und elektrisches Feld eines Wassermoleküls

Der Wasserdipol besteht aus 2 Protonen, die beide einfach positiv geladen sind, und einem Sauerstoffion, das doppelt negativ geladen ist. Der Winkel zwischen den beiden H-Atomen beträgt 105°.

Die Position der Protonen bzw. des Sauerstoffions wird durch die Positionsvariablen x1..x3 und y1..y3 gewählt. Die in diesem Beispiel verwendeten Maple-Befehle werden nicht näher erläutert, können aber im Beispiel "Potential und elektrisches Feld einer Punktladung" in diesem Worksheet nachgelesen werden.

> restart: with(plots):
> phi:=-2/sqrt(((x+x1)^2+(y+y1)^2)) + 1/sqrt(((x+x2)^2 + (y+y2)^2)) + 1/sqrt(((x+x3)^2+(y+y3)^2));
> x1:=0: y1:=0: x2:=-1.3: y2:=1: x3:=1.3: y3:=1:

> p1:=densityplot(phi*Heaviside(phi+5)*Heaviside(5-phi), x=-2..2,y=-2..1, grid=[60,60],style=patchnogrid):
> p2:=gradplot(phi,x=-2..2,y=-2..1,grid=[8,8], arrows=THICK,color=red):
> p3:=contourplot(phi,x=-2..2,y=-2..1, color=white, numpoints=400, contours=29):
> ttl:=`Feld u. Potential des Wassermoleküls`:

> display({p1,p2,p3},axes=none, scaling=constrained, title=ttl);

zurück zum Anfang

Quelle: Die ursprüngliche Ausarbeitung wurde von Volker Ceh und Armin Jerger im Rahmen der Maple-Working Group an der Fachhochschule Karlsruhe im Studiengang Sensorsystentechnik erstellt und von Prof. Dr. Westermann für die CD-ROM "Visualisierung elementarer mathematischer Begriffe mit Maple" überarbeitet. Diese Arbeit wurde teilweise gefördert durch ein Projekt aus dem Förderprogramm "Leistungsanreize in der Lehre (LARS)" des Ministeriums für Wissenschaft und Forschung, Baden-Württemberg, 1997/98. Weitere Maple-Projekte der Maple Working-Group der Fachhochschule Karlsruhe stehen unter der Internet-Adresse

http://www.fh-karlsruhe.de/fbmn/st/projekte/maple

zur Verfügung.

Literatur

T. Westermann
Mathematik für Ingenieure mit Maple, Band 2
Springer-Verlag Heidelberg, 1997

Klaus Weltner
Mathematik für Physiker, Band 2
Vieweg Verlag