> Differentialgleichung:  diff(y(x),x$2) + y + x = 0;

                        / 2      \
                        |d       |
                        |--- y(x)| + y + x = 0
                        |  2     |
                        \dx      /

> Randbedingungen:    y(0) = 0;      y(1) = 0;

                               y(0) = 0


                               y(1) = 0

# a) Nherungslsung mit einem eingliedrigen GALARKIN-Ansatz:
> y[1] := c[1]*x*(1-x);

                        y[1] := c[1] x (1 - x)

# Damit ergibt sich das Residuum aus der Differentialgleichung zu:
> R[1] := diff(y[1],x$2) + y[1] + x ;

                 R[1] := -2 c[1] + c[1] x (1 - x) + x

# Als Wichtungsfunktion ( Testfunktion /trial function) wird
> w :=x* (1-x);

                            w := x (1 - x)

# in die "GALERKIN-Forderung" gem (7.111) eingesetzt:
> Int(w*R[1], x= 0..1) = int(w*R[1], x= 0..1) ;

     1
    /
   |
   |   x (1 - x) (-2 c[1] + c[1] x (1 - x) + x) dx =
   |
  /
    0

        -3/10 c[1] + 1/12

# Dieses Integral muss nach (7.111) verschwinden, so dass sich die
# Konstante zu
> c[1] := solve( 1/12 -3*c[1]/10 = 0);

                             c[1] := 5/18

# ergibt. Damit lautet der eingliedrige Nherungsansatz folgendermaen:
> y[1] := subs(c[1] =%,y[1]);

                                 5 x (1 - x)
                         y[1] := -----------
                                     18

# Im Vergleich dazu ist die exakte Lsung durch
> y[ex] := sin(x)/sin(1) - x;

                                  sin(x)
                         y[ex] := ------ - x
                                  sin(1)

# gegeben.
# b) Nherung mit einem zweigliedrigen GALERKIN-Ansatz:
> y[2] :=x*(1-x)*( C[1] + C[2]*x);

                  y[2] := x (1 - x) (C[1] + C[2] x)

# Zur Bestimmung der beiden Konstanten werden zwei Wichtungsfunktionen
# bentigt:
> w[1] :=x* (1-x);   w[2] :=x^2*(1-x);

                          w[1] := x (1 - x)


                                   2
                          w[2] := x  (1 - x)

# Das Residuum folgt mit dem Nherungsansatz aus der
# Differentialgleichung:
> R[2] := diff(y[2], x$2) + y[2] + x;

  R[2] := -2 C[1] - 4 C[2] x + 2 (1 - x) C[2]

         + x (1 - x) (C[1] + C[2] x) + x

# Mit den beiden Wichtungsfunktionen erhlt man aus der Forderung  
# (7.111) zwei lineare Gleichungen zur Bestimmung der beiden Konstanten:
> Int(w[1]*R[2], x= 0..1) = int(w[1]*R[2], x= 0..1);

     1
    /
   |
   |   x (1 - x) (-2 C[1] - 4 C[2] x + 2 (1 - x) C[2]
   |
  /
    0

         + x (1 - x) (C[1] + C[2] x) + x) dx =

        -3/20 C[2] - 3/10 C[1] + 1/12

> Int(w[2]*R[2], x= 0..1)  = int(w[2]*R[2], x= 0..1);

     1
    /
   |    2
   |   x  (1 - x) (-2 C[1] - 4 C[2] x + 2 (1 - x) C[2]
   |
  /
    0

         + x (1 - x) (C[1] + C[2] x) + x) dx =

         13
        ---- C[2] - 3/20 C[1] + 1/20
         105

# Die Integrale mssen verschwinden , so dass man das folgende
# Gleichungssystem erhlt:
> with(linalg):
> A*C = a;

                               A C = a

# Darin ist { C } der gesuchte Lsungsvektor. Die Matrix [ A ] und der
# Vektor { a } sind obigen Integralen zu entnehmen: 
> A := matrix (2,2,[[3/10, 3/20], [3/20, 13/105]]);

                              [3/10    3/20]
                              [            ]
                         A := [        13  ]
                              [3/20    --- ]
                              [        105 ]

> a := vector ([1/12, 1/20]);

                          a := [1/12, 1/20]

> C := linsolve(A,a);

                                [71       ]
                           C := [---, 7/41]
                                [369      ]

# Damit lautet der zweigliedrige GALARKIN-Ansatz:
> y[2] := subs({C[1] =71/369,C[2]=7/41},y[2]);

                                      /71    7 x\
                    y[2] := x (1 - x) |--- + ---|
                                      \369   41 /

# Im folgenden Bild  sind die Ergebnisse mit Hilfe der MAPLE-Grafik
# dargestellt:
> plot({y[ex],y[1],y[2]}, x = 0..1);

# Mann erkennt, dass sich der zweigliedrige Ansatz kaum von der exakten
# Lsung unterscheidet, whrend der eingleidrige Ansatz merkliche
# Unterschiede aufweist ! 
> 
