### **Example 3.2.2 Series Solutions for Non-isothermal Catalyst Pellet - Multiple Steady States**

> restart:

> with(plots):

The governing equation is entered here:

> eq:=diff(c(x),x$2)=Phi^2\*c(x)\*exp(gamma\*beta\*(1-c(x))/(1+beta\*(1-c(x))));

The values for the parameters are entered here:

> eq:=subs(gamma=20,beta=0.8,eq);



The boundary condition at  is entered here:

> bc:=c(x)-1;



The order of the series solution is specified and the governing equation is solved as a function of c1, the concentration at the center, and Φ:

> Order:=8;



> sol:=dsolve({eq,c(0)=c1,D(c)(0)=0},{c(x)},type=series);



The series solution obtained is stored in ca:

> ca:=convert(rhs(sol),polynom);



The boundary condition at  is evaluated using the series solution obtained:

> eqc:=subs(c(x)=ca,bc);




> eqc:=subs(x=1,eqc);



The equation for c1 is plotted as a function of c1. We observe that there are four solutions:

> plot(subs(Phi=0.2,eqc),c1=0..1,view=[0..1,-1..1],title="Figure Exp. 3.2.2.",thickness=4);



The values for the constant c1 are obtained using the 'fsolve' command.

> cc[1]:=fsolve(subs(Phi=0.2,eqc),c1=1);



> cc[2]:=fsolve(subs(Phi=0.2,eqc),c1=0.8);



> cc[3]:=fsolve(subs(Phi=0.2,eqc),c1=0.0);



> cc[4]:=fsolve(subs(Phi=0.2,eqc),c1=0.03);



We obtain four different solutions for c1. These values for c1 and Φ are substituted in the series solution obtained and plots are made:


> p1:=plot(subs(c1=cc[1],Phi=0.2,ca),x=0..1,thickness=4,color=black,axes=boxed):

> p2:=plot(subs(c1=cc[2],Phi=0.2,ca),x=0..1,thickness=4,color=blue,axes=boxed):


> p3:=plot(subs(c1=cc[3],Phi=0.2,ca),x=0..1,thickness=4,color=brown,axes=boxed):

> p4:=plot(subs(c1=cc[4],Phi=0.2,ca),x=0..1,thickness=4,color=red,axes=boxed):

> display({p1,p2,p3},title="Figure Exp. 3.2.3.",labels=[x,c]);



> display(p4,labels=[x,c],title="Figure Exp. 3.2.4.");



We observe that the first three values of c1 make sense and we discard the fourth value. There is no guarantee that the solution obtained is the converged one. The accuracy and convergence of the series solution are analyzed below by increasing the number of terms in the series.

> Order:=16;



> sol:=dsolve({eq,c(0)=c1,D(c)(0)=0},{c(x)},type=series):

> ca:=convert(rhs(sol),polynom):

> eqc:=subs(c(x)=ca,bc):

> eqc:=subs(x=1,eqc):

> cc2[1]:=fsolve(subs(Phi=0.2,eqc),c1=1);



> cc2[2]:=fsolve(subs(Phi=0.2,eqc),c1=0.8);



> cc2[3]:=fsolve(subs(Phi=0.2,eqc),c1=0.0);



> for i to 3 do print(cc[i],cc2[i]);od;



We observe that the first value for c1 has converged and the next two values have not converged. Next, the order is increased to 20.

> Order:=20;



> sol:=dsolve({eq,c(0)=c1,D(c)(0)=0},{c(x)},type=series):

> ca:=convert(rhs(sol),polynom):

> eqc:=subs(c(x)=ca,bc):

> eqc:=subs(x=1,eqc):

> cc3[1]:=fsolve(subs(Phi=0.2,eqc),c1=1);



> cc3[2]:=fsolve(subs(Phi=0.2,eqc),c1=0.8);



> cc3[3]:=fsolve(subs(Phi=0.2,eqc),c1=0.0);



> for i to 3 do print(cc[i],cc2[i],cc3[i]);od;



We observe that the first value for c1 has converged (three digit accuracy). The second value of c1 has converged to two digit accuracy. The third value has not converged yet. But, the order of magnitude for the third value of c1 has converged. Next, plots are made for three different values of c1.


> p1:=plot(subs(c1=cc3[1],Phi=0.2,ca),x=0..1,thickness=4,color=black,axes=boxed):

> p2:=plot(subs(c1=cc3[2],Phi=0.2,ca),x=0..1,thickness=4,color=blue,axes=boxed):

> p3:=plot(subs(c1=cc3[3],Phi=0.2,ca),x=0..1,thickness=4,color=brown,axes=boxed):

> display({p1,p2,p3},labels=[x,c],title="Figure Exp. 3.2.5.");

>



Multiple steady states in a rectangular catalyst pellet were analyzed in this example. This problem will be revisited later in this chapter.

>